Counterfeit Monkey — 13 of 292

Emily Short

Release 5

Section 2 - Score

[Score is pretty old-school here: it marks progress towards the end game and provides the player with a review of significant achievements so far, as well as encouraging the player that he did the right thing at certain junctures.

Optional accomplishments are not included -- those are reserved for the achievement system -- so there are no Last Lousy Points. A player who gets to the end of the game should have the full hundred.]

The new notify score changes rule is listed instead of the notify score changes rule in the turn sequence rulebook.

This is the new notify score changes rule:

if the score is not the last notified score:

say "[first custom style]";

let diff be the score minus the last notified score;

if diff is less than 0:

let diff be 0 minus diff;

say "[bracket]Your score has gone down by [diff in words] point[s][if score is greater than diff] and is now [score in words][end if].[close bracket]";

otherwise:

say "[bracket]Your score has gone up by [diff in words] point[s][if score is greater than diff] and is now [score in words][end if].[close bracket]";

say "[roman type][paragraph break]";

now the last notified score is the score;

Table of Tasks Achieved

PointsCitationTime
1 "using the letter-remover"a time
1"using the gel"
1"using the spinner"
1"using the origin paste"
1"using the synthesizer"
1"getting a product of the homonym paddle"
1"using the T-inserter"
1"using the anagramming gun"
1"using the umlaut punch"
1"using the vowel rotator"
2"returning a library book to its proper home"
3"passing through the temporary barrier"
3 "winning the gel"
3 "opening the locker"
3"retrieving the backpack"
3"fueling our car"
3"repairing our car"
3"winning a barroom bet"
3"arranging contact with Slango through his lady friend"
3"visiting the dead drop"
3"reading a legend"
3"lifting abstraction limits on the letter-remover"
3"lifting animate limits on the letter-remover"
3"gaining access to the synthesizer"
3"acquiring a keycard"
3"breaking the Spirit of Atlantis (in cardboard form)"
3"profiling the T-inserter"
5"traveling by car"
5"meeting Slango"
5"passing the secretarial test"
10"acquiring a sought-after invitation"
15"returning to the yacht"

To record (T - text) as achieved:

choose row with a citation of T in the Table of Tasks Achieved;

if there is no time entry begin;

change time entry to the time of day;

award (points entry) points;

end if.

The announce the score rule is not listed in any rulebook.

Carry out requesting the score:

if the score is 0:

say "So far you are without points.";

otherwise:

say "You have earned [score] point[s]:";

repeat through the Table of Tasks Achieved in time order:

say "[line break] [points entry] point[s] for [citation entry]";

say paragraph break.

Report requesting the score:

if the number of entries in the list of remaining letters is 26:

say "You have not yet removed any letters from anything.";

otherwise if the number of entries in the list of remaining letters is 0:

say "You have at some time removed every letter from something.";

otherwise:

say "You have not yet removed [disjoint list of remaining letters] from anything.";

follow the list achievements rule.

To say disjoint (L - a list of indexed texts):

let N be the number of entries in L;

repeat with I running from 1 to N:

say entry I in L;

if I is N - 1:

say ", or ";

otherwise unless I is N:

say ", ".

Table of Rankings

Score Rank
0 "Graduate Student"
10"Escapee"
20"Petty Criminal"
30"Smuggler"
40"Industrial Spy"
50"Corporate Espionage Expert"
60"Subversive Element"
75"Enemy of the State"
100"Successful Revolutionary"