Counterfeit Monkey — 138 of 292

Emily Short

Release 5

Section 5 - Higgate's Office

Higgate's office is an office. It is privately-controlled.

Higgate's office door is west of the Language Studies Department Office. Higgate's office door is a door. It is open and lockable and scenery. Understand "west door" as higgate's office door when the location is the Language Studies Department Office.

Understand "bureau tape" or "tape" as Higgate's office door when Higgate-arrested has happened.

Report higgate discussing how we might return a book:

say "[response of the noun][paragraph break]";

try higgate exiting;

say "'After you,' says Higgate. 'I assume it's safe to leave for a minute; if anyone is coming for Lojban Tea we'll see them in the hall.' [run paragraph on]";

try higgate approaching Samuel Johnson Hall;

try approaching Samuel Johnson Hall;

try Higgate unlocking the seminar door with the lsr-key;

try HIggate opening the seminar door;

try Higgate approaching the Seminar Room;

try going southwest;

set the interlocutor to Higgate instead..

Instead of doing something in the presence of Higgate when the noun is the synthesizer or the second noun is the synthesizer or the noun is the plexiglas case or the noun is the screws or the second noun is the plexiglas case or the second noun is the screws:

say "Higgate may be a little unworldly, but there is no way she'd let us mess with the synthesizer without interference. We'll have to hope she is willing to leave us in here."

Instead of going somewhere when the location is the Seminar Room and Higgate is in the location:

say "[You] got in here on the pretext of putting the book away. It would be odd to leave again without doing so."

After putting the Problem of Adjectives on the LSR Bookcase:

say "[You] take a moment to find the proper place for the book.

The sound of discussion comes from down the hall: two voices speaking in Lojban, and then a male voice interrupting. 'Do you have a lic[ense] for this conversation?' it asks.

'Excuse me,' Higgate says. 'I'd better go see to that.'";

try Higgate approaching higgate's office;

reset the interlocutor;

now higgate's office door is closed instead.

Instead of examining Higgate's office door when Higgate-arrested has happened:

say "The door is closed and sealed over with Bureau tape to prevent anyone from tampering with it in any way."

Instead of knocking on Higgate's office door when Higgate's office door is closed:

if higgate-arrested has happened:

say "The door is sealed with Bureau tape. Evidently they are planning to search more carefully later.";

otherwise:

say "'Come in!' shouts someone."

Instead of opening Higgate's office door when Higgate's office door is closed:

let N be the number of entries in the path so far of the player;

if N is greater than 1:

say "[path-walked so far]";

otherwise:

clear the path-walked for the player;

if higgate-arrested has happened:

say "The door is sealed with Bureau tape. Evidently they are planning to search more carefully later." instead;

say "[one of][You] open the door to find two students, a boy and a girl, sitting at Higgate's table. The boy is sipping tea and the girl is paging madly through the Lojban book. 'Oh,' says Higgate. 'You found what you needed, I hope? I'm afraid [you] [are] busy now.'

So I duck us back out and close the door[or]I don't think [you] need anything else, and it would be mean to interrupt their tea again[stopping].".

Instead of listening to Higgate's office door when Higgate's office door is closed:

if higgate-arrested has happened:

say "Dead silence." instead;

say "Putting our ear to the door, [you] hear [one of]a girl's voice stumbling over a question[or]Professor Higgate saying something rapid and fluent[or]a boy laughing[stopping]."

Higgate's Office is west of Higgate's office door. "Higgate got about 30% finished with a stylish decorating scheme and then got distracted, leaving everything in a unsettled state. A few of her books are arranged on a very nice [rosewood bookshelf], which looks Asian[if the small figurines are on the bookshelf] and is ornamented with [small figurines][end if]; all the rest of her library is stacked higgledy-piggledy in [plastic cartons]."

The rosewood bookshelf is a supporter in Higgate's Office. It is scenery. Some small figurines are on the rosewood bookshelf. The small figurines are scenery. The description of the small figurines is "They depict mostly characters from popular children's fiction: Professor Higgate has a particularly strong and inexplicable fetish for the Wizard of Oz."

Some plastic cartons are containers in Higgate's Office. They are scenery. The description of the plastic cartons is "Traffic-cone orange and very unattractive."

[Some trim is scenery in Higgate's office. The description is "The trim [--] no more than a line around the top of the walls, really [--] is a handsome dark green that sets off the rosewood."]

[A paint is in Higgate's Office. "Left over from the decoration process is some paint." The indefinite article is "some". The description is "It looks as though it's left over from Higgate's work on the trim in the office."

The paint can be released or retained. The paint is retained.

Instead of taking the paint when the paint is retained:

say "Higgate looks like a sweetheart, and in many respects she is, but if we start stealing her stuff right in front of her there's a very good risk she'll call security."

Instead of waving the letter-remover at the paint when the paint is retained:

say "Higgate might mind our modifying her stuff without permission." ]

When play begins:

let N be a random chair in Higgate's Office;

move Professor Higgate to N.

Rule for writing a topic sentence about Professor Higgate when Higgate is on a chair (called the special-target):

say "[Professor Higgate] is sitting at [an oval table][if something is on the oval table], on which are spread [a list of things on the oval table][end if]. [run paragraph on]".

Rule for writing a topic sentence about Professor Higgate when Higgate is in the Seminar Room:

say "[Professor Higgate] waits a little absent-mindedly nearby, looking over [the LSR Bookcase]. [run paragraph on]".

Rule for disclosing exterior of Professor Higgate when Professor Higgate is on a chair:

do nothing instead.

Professor Higgate is an alert woman in Higgate's Office.

The description is "Professor Higgate is about forty-five, very tall and slim, with a short, no-nonsense hairstyle. Indeed everything about her self-presentation suggests that she has studied how to make herself acceptably professional in the shortest possible time each day, and now adheres to this plan with absolute rigor.

What she might look like in some other setting, such as on a date or at a formal dinner, is beyond my ability to imagine."

The introduction is "Higgate is the second reader on my dissertation committee, and a conlang expert [--] that is, Constructed Languages. It was a seminar with her that really got me thinking about utopian linguistics, and she's been very supportive, though cautious[if Professor Waterstone is introduced]. She and Professor Waterstone don't always get along that well[end if]."

The oval table is a privately-named supporter in Higgate's Office. It supports a book called Complete Lojban. Understand "table" or "oval table" as the oval table. [Disambiguate from University Oval in GO TO commands.]

The description of Complete Lojban is "The book is bound in an ugly yellow binding and has a number of small sticky notes sticking out of it." Complete Lojban is improper-named.

The introduction of Complete Lojban is "I used to have a copy of this myself: it's uninventively called [i]Complete Lojban[/i] and appeared with about a dozen similar texts in our conlang survey seminar."

Understand "ugly" and "yellow" and "binding" and "small sticky notes" and "sticky notes" and "notes" as Complete Lojban.

Rule for printing the name of Complete Lojban when Complete Lojban is not proper-named: say "[roman type]ugly yellow book"

Carry out examining Complete Lojban: now the noun is proper-named.

The sugar bowl is a container on the oval table. Instead of searching the sugar bowl, say "It is about a quarter full."

The teapot is a container on the oval table. The teapot is openable and closed. The description is "Black and Japanese-styled." Understand "tea" as the teapot. Instead of searching the teapot: say "[You] peek inside. The tea has evidently been sitting on the leaves a long time, because it is powerful and looks almost like coffee."

Instead of drinking the teapot:

say "To judge by the col[our] of the tea, it has been steeping so long as to be nearly vertical."

The oval table supports a book called Heart to Heart. Understand "romance" or "novel" as Heart to Heart.

The description of Heart to Heart is "The cover shows two women in a steamy embrace, so I'm going to guess it's a romance novel. As language is one I haven't ever learned, I can't read the title." Heart to Heart is improper-named.

Rule for printing the name of Heart to Heart: say "[roman type]romance novel in some heavily accented language".

Instead of taking something which is on the oval table:

say "Professor Higgate frowns as [you] reach for [the noun]. 'You may have noticed,' she says, in the kind of voice that always withered our hearts in seminar, 'that there are certain social expectations about touching the possessions of other people.'

My fingers relax their grip instinctively."

lsr-key unlocks seminar door. lsr-key is carried by Higgate. The printed name of the lsr-key is "small key". Understand "small" as the lsr-key.

Rule for deciding the concealed possessions of Higgate:

if the particular possession is the lsr-key:

yes.

Instead of putting something on the oval table:

say "Why get our stuff mixed up with Professor Higgate's? Besides, there's not a lot of space left there anyway."

Report Professor Higgate saying hello to the player:

if Higgate recollects that we do not speak Lojban, queue English-greeting instead;

otherwise queue lojban-greeting instead.