Counterfeit Monkey — 166 of 292

Emily Short

Release 5

Section 5 - Tunnel through Chalk

The Tunnel through Chalk is below Surveillance Room. Tunnel through Chalk is indoors and forbidden. "This passage has been cut through natural cliff rock and looks older than the Bureau itself. The walls are rough-hewn, exposing [sedimentary strata]. Here and there it looks as though someone has actually excavated a fav[our]ed rock or relic."

The sedimentary strata are scenery in the Tunnel through Chalk. The description is "Layers of slightly varying chalk col[our], some of which are embedded with tiny seashells and other fossil evidence." Understand "layers" or "chalk" or "seashells" or "tiny" or "shells" or "evidence" or "fossil evidence" as the sedimentary strata.

Every turn when the location is Tunnel through Chalk:

if a random chance of 1 in 3 succeeds:

say "[one of]The air stirs with a breeze from the east[or]A breeze along the passage stirs the dust[or]There's a faint tang of salt air[or]Something like the cry of a seagull comes down the passage[as decreasingly likely outcomes]."

Instead of smelling Tunnel through Chalk:

say "The air does smell fresher here."

The upward-spiral staircase is an up-staircase in Tunnel through Chalk. The printed name of the upward-spiral staircase is "spiral staircase". Understand "spiral" as the upward-spiral staircase.

Understand "raise [portcullis]" or "lift [portcullis]" as opening.

The portcullis is a door. It is east of Tunnel through Chalk and west of Personal Apartment. "[if the location is Tunnel through Chalk]Blocking the far end of the corridor is a metal [portcullis][otherwise]The metal [portcullis] guards the way back[end if]. [portcullis status]."

The description of the portcullis is "Heavy black metal bars, left from a much earlier state. [portcullis status]."

To say portcullis status:

say "It is currently [if the portcullis is open]raised[otherwise]lowered[end if][if the jack wedges the portcullis] a few feet by [a jack][end if][if something is on the pulley]. From the pulley above the portcullis hangs [a list of things which are on the pulley][otherwise]. There's a pulley and hook arrangement above the portcullis, but the hook is empty[end if]".

Instead of searching the portcullis:

if the player is in Tunnel through Chalk:

say "Thanks to the angle of the tunnel, it's hard to see much of the room beyond, save that the rough rock walls have been paneled, and [you] can make out the edge of a desk or table, probably an old one. There's some source of natural light through there.";

otherwise:

say "The pulley mechanism is clearly visible but is on the far side of the bars."

The pulley is part of the portcullis. It is a supporter. Understand "rope" or "pulley" or "hook" as the pulley. The description of the pulley is "Rope runs from the top of the portcullis over pulleys and down to a hook. It looks like a contrivance to help open the portcullis."

Check putting the weight on the pulley:

say "This weight isn't substantial enough, and also provides no loop or ring that would let it hang from the hook." instead.

Check putting an unhookable thing on the pulley:

say "[The noun] do[es]n't fit on the hook." instead.

Definition: a thing is unhookable:

if it is the counterweight:

no;

if it is the ordinary-counter:

no;

if it is floppy:

no;

yes.

[And to account for cases where you make an unhookable thing on the pulley via letter-manipulating something that was previously there:]

Every turn when something unhookable is on the pulley (this is the portcullis empty rule):

if the player can see the pulley:

say "[The list of unhookable things on the pulley] fall[s] to the ground.";

now every unhookable thing on the pulley is in Tunnel through Chalk.

Sanity-check putting something on the portcullis:

try putting the noun on the pulley instead.

Check putting something on the pulley when something is on the pulley:

say "The hook can only really hold one thing at a time. [run paragraph on]";

while something (called the current content) is on the pulley:

try taking the current content;

if the current content is on the pulley:

stop the action.

Every turn when the counterweight is not on the pulley and the portcullis is open (this is the portcullis fall rule):

unless something wedges the portcullis:

now the portcullis is closed;

if the player can see the portcullis:

say "The portcullis crashes shut."

Check opening portcullis:

if the counterweight is not on the pulley:

say "[You] strain at the base of the gate, but the portcullis is much too heavy for us to lift unaided. We need some kind of mechanical advantage." instead.

Report putting something on the pulley:

say "[You] hang [the noun] on the hook." instead.

Report putting the counterweight on the pulley:

say "[You] hang [the noun] on the hook[if the portcullis is closed]. The portcullis shifts slightly but doesn't rise on its own. Perhaps with a little help, though[end if]." instead.

After putting the counterweight on the pulley when the jack wedges the portcullis:

now the jack does not wedge the portcullis;

say "[You] hang [the noun] on the hook, and the portcullis opens to its full extent, leaving the jack free."

Understand "use [jack] on [something]" as propping it with.

Check propping the portcullis with something which is not the jack:

say "[The second noun] [is-are] not strong enough for such a heavy door." instead.

Sanity-check opening the portcullis when the player carries the jack:

if the player is hurrying:

say "[path-walked so far]There [you] try propping the portcullis with the jack.[paragraph break]";

clear path-walked for player;

increase path description count by 1;

try propping the portcullis with the jack instead.

Sanity-check unlocking the portcullis with the jack:

try propping the portcullis with the jack instead.

Report propping the portcullis with the jack:

say "[You] slip [the jack] under the portcullis and raise it a few feet [--] enough for us to slip past." instead.

After deciding the scope of the player when the location is Personal Apartment or the location is Tunnel through Chalk:

if the portcullis is wedged by something (called the impediment):

place the impediment in scope.

Instead of pulling the pulley when the counterweight is not on the pulley:

if the portcullis is closed:

say "Even pulling from above, [you] can't budge the portcullis. Some additional weight is required.";

otherwise:

say "The portcullis is already open and the counterweight nearly to the ground."

Instead of pulling something which is on the pulley:

if the noun is the counterweight:

try opening the portcullis;

otherwise:

try pulling the pulley.

[Nothing makes this explicit, but in addition to being part of the counterweight, the counter measures numbers of visits to the oracle in a given month. For the most part people do not open the portcullis and consult with Atlantida from the outside instead, as they are increasingly afraid of her.]

The ordinary-counter is on the pulley. The printed name of the ordinary-counter is "counter". The description of the ordinary-counter is "One of those devices with a press-button to increment a number, to assist with counting things like the number of people attending an event. There's also a loop to let the user wear it over one finger. The counter currently reads [counter-state]." The ordinary-counter has a number called the counter-state. The counter-state of the ordinary-counter is 17.

Understand "press-button" or "button" as the counter. Understand "counter" as the ordinary-counter. The ordinary-counter is wearable.

Instead of pushing the ordinary-counter:

increase the counter-state of the ordinary-counter by 1;

say "Click! The counter now reads [counter-state]."