Section 5 - Galley
The Galley is below the Navigation Area. It is nautical. It is indoors. The description is "Smaller than the kitchen in a comfortable house, but carefully and elegantly fitted, with an electric stovetop, a convection oven/microwave, a tiny refrigerator, a sink: enough, in short, to serve the crew of three on long trips.[one of] I guess even a fairly big boat is still small on the inside, eh?[or][stopping]
There's even a little washing machine, for items too big to hand-wash in the sink.".
A built-in table is scenery in the Galley. It is a supporter. The description is "When the weather is good and there is nothing urgent happening, you all often eat out on the sunning deck, which is more congenial; but at other times you take your meals down here, on this table. The seating is built-in.". Some seating is part of the built-in table. The seating is an enterable supporter. Understand "built-in seating" as the seating.
The galley cabinet is a scenery cabinet in the Galley.
The galley cabinet contains a bottle of ouzo and assorted staples. The description of the bottle of ouzo is "Left over from a job in Crete. It's been going slowly because Slango doesn't let anyone get drunk on [i]True Macaque[/i] and a single slug of this stuff is the upper limit."
The description of the assorted staples is "Various long-keeping foods, mostly cooked by Slango. You and Brock occasionally pitch in, but more frequently do the washing up instead. There's enough here to feed the three of you, frugally and without frills, for about a month and a half."
Some gameshelves are scenery in the Galley. The printed name is "built-in shelves". Understand "shelf" or "shelves" or "built-in" as the gameshelves.
On the gameshelves is a game-selection. Understand "games" or "game" or "battered" or "selection" or "selection of games" as the game-selection.
Rule for writing a paragraph about something which is on the gameshelves:
say "On the port wall, built-in shelves hold [a list of things on the gameshelves]."
The description of the game-selection is "Oh, all sorts: Boggle and Scrabble, which you always win and which therefore Brock and Slango only play when they're in a mood for cheering you up. Monopoly, dusty with disuse. Puerto Rico. Arkham Horror. It's surprising what even Brock will admit to being amused by in the course of a long evening at sea." The printed name of the game-selection is "battered selection of games".
[Arkham Horror is a game designed by G. Kevin Wilson, who also happens to be the originator of SPAG magazine and an enthusiastic contributor to the early IF community. It is also an incredibly detailed game with a bazillion pieces, and about as unsuitable for shipboard play as any boardgame could be.]
Understand "boggle" or "scrabble" or "monopoly" or "arkham" or "horror" or "puerto" or "rico" as the game-selection.
Instead of doing something other than examining when the noun is the game-selection or the second noun is the game-selection:
if looking at the game-selection through something:
continue the action;
say "This doesn't seem to be a game-playing sort of occasion."
Some wide portholes are portholes. They are in the galley.
The washing machine is a closed openable scenery container in the Galley. The description is "It's efficient enough, but only works when plugged into water and power in a marina. It would be too draining to run off the yacht's resources in open sea. [paragraph break]Besides, you don't have a dryer, which means laundry has to be put up on a string above-decks, and that's not a practical thing to do when you might be having to make a fast get-away in the near future."
A refrigerator called a galley refrigerator is in the Galley.
The printed name is "[if looking]refrigerator[otherwise]galley refrigerator[end if]".
The description is "Like the other fittings of the kitchen, it's handsomely sleek with shiny black surfaces. An unnecessary frill, but it fits the bored-playboy-yachts-around-Mediterranean cover that Slango likes to put up. (Brock plays the lead role.)
The rest of the food is in the cabinet."
A stove called a galley stove is in the Galley. The description of the galley stove is "A perfectly smooth, easy-to-clean black surface with electric burners underneath."
A sink called a galley sink is in the Galley. The description of the galley sink is "Stainless steel, and very clean."
The multipurpose oven is fixed in place scenery in the Galley. It is an openable closed transparent container. Understand "convection" or "microwave" as the multipurpose oven. The description is "A versatile piece of machinery that can either microwave or convection-heat things. It's not terribly powerful at either task, but it suffices and moreover is very compact."
When play begins:
let target be a random freezer compartment which is part of the Galley refrigerator;
move the fig ice cream to the target;
move the frozen dinners to the target;
move the bottle of vodka to the target;
let target oven be a random oven which is part of the Galley stove;
remove the target oven from play. [because we want a special microwave/convection oven in there instead.]
A fig ice cream is a thing. The indefinite article is "some". The description is "Brock got this for a lark, but it turns out no one likes it."
Some frozen dinners are a thing. The description is "French frozen food, which I gather from your thoughts [--] obviously I've never tasted the stuff [--] is miles better than any other kind of frozen food, in the sense of actually tasting good."
A bottle of vodka is a thing. The description is "Half empty, typically drunk exclusively by Brock."
A jar of caviar is a thing. It is in the Galley refrigerator. The description is "Most of it is gone, used up in Brock's great crepes experiment of last weekend."
Instead of taking something which is in a freezer compartment when the location is the Galley:
say "No one's hungry right now."
Instead of inserting something into a freezer compartment:
say "There's no point in freezing [the noun]."