Counterfeit Monkey — 207 of 292

Emily Short

Release 5

Chapter 7 - Authentication Scope

An authentication scope is a kind of thing.

The secretary carries an authentication scope called the Regulation Authentication Scope.

In the backpack is an authentication scope called a monocle. The description of the monocle is "This is no mere fashion accessory. It is the very top grade of authentication scope, designed for people who have to use them all day, and normally available only to employees of the Bureau of Orthography. If [you] look through the monocle at something, [you] can see its true nature, regardless of spelling changes." The monocle is wearable. The monocle is illegal.

The introduction of the monocle is "You like that? I thought you might be impressed. My father got it for me. 'For research,' he said, but I think he knew I just coveted them. At any rate, you're not the only one with equipment."

The monocle is essential.

The monocle covers the face-area.

Last after examining something when the player wears the monocle:

if the noun is not the monocle:

try looking at the noun through the monocle;

continue the action.

After wearing the monocle:

if the player is not enclosed by the kayak:

say "Everything turns computer-monitor green when viewed through our right eye. And staring fixedly at anything will turn up its authenticity status."

Understand "stare at [something]" or "stare fixedly at [something]" as examining.

The description of an Authentication Scope is usually "It looks like a small hand-held telescope, or perhaps a very posh kaleidoscope: all brown leather and brass fittings, and a good heft indicating quality materials. The sophisticated electronics are all concealed within. If [you] look through the scope at something, [you] can see its true nature, regardless of spelling changes."

Instead of searching a scope:

try looking at a random thing in the location through the noun.

Understand "look at [something] through/with/using [something preferably held]" as looking at it through.

Understand "examine [something] with/through [something preferably held]" as looking at it through.

Understand "look through/with/using [something preferably held] at [something]" as looking at it through (with nouns reversed).

Looking at it through is an action applying to one visible thing and one carried thing.

Check an actor looking at something through something:

if the second noun is not an Authentication Scope

begin;

if the actor is the player, say "[The second noun] won't give us a clear view of [the noun]." instead;

stop the action;

end if.

Check an actor looking at something through something:

if the noun is an authentication Scope and the second noun is the noun

begin;

if the actor is the player, say "[You] can't look through [the noun] at itself." instead;

stop the action;

end if.

Check an actor looking at something through something:

if the noun is the actor

begin;

if the actor is the player, say "[You] can't turn the scope on ourselves [--] which might be just as well, really, because I think it would give me a headache to see the two of us conjoined at the hip. Or however the scope would show us, anyway." instead;

stop the action;

end if.

Carry out looking at a mirror through something:

say "[The noun] [is-are] real enough, and [the second noun] pings approvingly.

But laid over the reflection we can see the two of us as we used to look: you a little shorter than our current body, me taller and male and needing a shave. I'm not sure whether it makes me feel better or worse to see us like that." instead.

Test reflecting-bug with "x reflection / wear monocle / x reflection / look at reflection through monocle" holding the monocle in sigil street.

Carry out looking at it through:

if the noun is original or the noun is disguised:

[play the sound of scope success;]

say "[The second noun] pings happily as [you] sight [the noun] with the crosshairs.";

otherwise:

[play the sound of scope failure;]

say "There is a dismissive blatt from [the second noun], and transposed over [the noun] is a faint, [if the noun is edible and the noun is proffered by something inedible]unappet[izing][otherwise]greenish[end if] image of [a list of things which proffer the noun]."

Report someone looking at something through something:

if the noun is original, say "In response [the actor] looks through [the second noun] at [the noun], then nods briskly. '[one of]The genuine article[or]Definitely not fake[or]Looks clean[or]Not a forgery[or]Real[or]Yup, authentic[at random].'";

otherwise say "Thoughtfully [the actor] peers through [the second noun] at [the noun], then frowns. '[one of]Fake[or]An obvious forgery[or]Not at all the real thing[or]Bogus[or]I hope that came with a money-back guarantee[as decreasingly likely outcomes]!' [it-they of the actor] [one of]say[s][or]remark[s][or]exclaim[s][as decreasingly likely outcomes]."

After the secretary looking at the disguised pass through a scope:

say "The secretary raises her Authentication Scope to look at the pass. There is a moment of silence. The scope does nothing.";

now the player is allowed.

After the secretary looking at the undisguised pass through a scope:

say "The secretary raises the scope to look at the pass. Her eyes widen at the blatant forgery. 'Stay right there, buddy,' she says. From her tone of voice, this is obviously the most entertaining thing that has happened to her this fiscal year.

It is also a wholly unnecessary command, because she has pressed a button that puts the antechamber into lock-down mode.

There follows a long interrogation and a short trial.";

end the game saying "[You] pass the rest of our days stamping lic[ense] plates together"

After someone looking at the player through an authentication Scope:

say "[The actor] turns the Authentication Scope on us. You seem calm, but I'm nervous as hell.

But I have to say, you were right: the scope neither beeps nor blatts. [The actor] tries twisting the end as though bringing a telescope into focus, but nothing changes.

'Must be broken,' mutters [the actor]."

First carry out looking at the inscription through an authentication scope:

say "[The second noun] begins to whirr and whirr, as though something inside has caught in an unresolvable loop. After a very long time, it whirrs down again without any noise of rejection or acceptance." instead.