Counterfeit Monkey — 210 of 292

Emily Short

Release 5

Section 2 - Converting nouns

Understand "rub [gel] on/onto/to [something]" as putting it on. Understand "rub [tube] on/onto/to [something]" as putting it on. Understand the commands "smear" as "rub".

Understand "apply [gel] on/onto/to [something]" as putting it on. Understand "apply [tube] on/onto/to [something]" as putting it on.

Understand "use [gel] on [something]" as putting it on. Understand "use [tube] on [something]" as putting it on.

Understand "[gel] [something]" or "[tube] [something]" as putting it on.

Understand "[paste] [something]" as putting it on.

Sanity-check putting the tube on something:

say "Unfortunately, there's hardly any gel remaining in the tube." instead.

Sanity-check putting the restoration gel on something irretrievable:

if the second noun contains the tub:

try taking the tub;

if the second noun contains the letter-remover:

try taking the letter-remover;

if the second noun is irretrievable:

say "Since [the second noun] contain[s] [if the second noun encloses the tub][the tub][otherwise]something useful[end if], it might be a bad idea to change its form. [You] might not be able to get the contents back." instead.

[Because it's possible to change something into an object that becomes fixed in place in the backpack, or too heavy to move...]

Before putting the restoration gel on something which is in the backpack:

try taking the second noun;

if the player does not carry the second noun:

say "It seems best not to word-change things that are in the backpack." instead.

[And now special cases of description: ]

Instead of putting the restoration gel on the Origin Paste:

say "[You] dip out some of the gel and touch it to the Origin Paste. There is a violent, fizzy reaction; lavender and mint fumes; and then the two substances appear to have worked out their mutual antipathy. The dollop of gel is gone, the cake of paste slightly smaller than it used to be."

Instead of putting the restoration gel on something:

say "[You] dip out [if the heft of the second noun is 1]fingertip-coating[otherwise]pea-sized[end if] quantity of gel and rub it gently onto [the second noun]. [run paragraph on]";

gel-convert second noun.

Instead of putting the restoration gel on something fluid:

say "[You] just touch a coated fingertip of gel to [the second noun]. [run paragraph on]";

gel-convert second noun.

Instead of putting the restoration gel on yourself:

if atlantida-woman is seen:

say "[You] optimistically rub in a little gel, but it doesn't make any difference. We're stuck this way, for good.";

else:

say "A fingertip-dab isn't enough to undo the doubling-up [you] experienced, but if [you] applied more, there's a real chance [you][']d come apart into a you and a me. And [you] can't afford that right now."

Yourself can be gelled or ungelled. Yourself is ungelled.

Instead of wearing the restoration gel:

try putting the restoration gel on yourself.

[Instead of putting the restoration gel on yourself during Nightfalling:

if the location encloses someone who is not the player:

say "[You][']d rather do this where we have some privacy, just in case the splitting is embarrassing or leaves us both nude or something." instead;

if Brock is in the repository:

say "Let's gel Brock first and make sure he's all right; then [you] can use the rest of the gel with impunity, however much [you] need." instead;

if the player is ungelled:

now the player is gelled;

say "At last, time to get out of this double existence. You scoop out a big handful of the restoration gel and start applying it to both arms like you're putting on mosquito repellant for a swamp raid.

It tingles and burns, fizzing against the existing Origin Paste that held us together this long and protected us from authentication scopes.

[You] dip again and slather on more: over our face, neck, hair even. [You] just about empty the whole tub.

It's cool now, not reacting against anything.

It also isn't working.

[You] [are] stuck. For some reason, for now, you and I are stuck together like this.";

otherwise:

say "There's not much gel left." ]

Instead of putting the restoration gel on an original person:

if the second noun is an animal:

continue the action;

otherwise:

say "[one of][You] dip out [if the heft of the second noun is 1]fingertip-coating[otherwise]pea-sized[end if] quantity of gel and approach [the second noun] with it. 'Hey!' says [the second noun]. 'That was really cold! What do you think you're doing?'

But no exciting conversions occur.[or][You] get some gel and try to be subtle about touching it to [the second noun], but [it-they of second noun] shies away, startled. Well, it likely wouldn't have had an effect anyway.[stopping]".

[Before putting the restoration gel on something which encloses the player:

say "Are you insane? If [the second noun] goes away, we'll go too." instead. ]

Instead of someone trying touching the restoration gel:

if the person asked can touch the restoration gel:

gel-convert the person asked;

rule succeeds.

Definition: a thing (called itself) is original if it proffers itself and it is proffered by exactly one thing.

To gel-convert (item - an object):

if the item is not original:

abide by the dangerous destruction rules for the item;

let destination be home for the item;

now everything which proffers the item is in the destination;

[play the sound of gel splort;]

let description needed be false;

if exactly one unseen thing (called the parent) proffers the item:

now description needed is true;

say "With an audible SPLORT, [the item] become[s] [a list of things which proffer the item][if the destination is the location and the holder of the item is not the location] and falls to the ground[end if]. ";

if description needed is true:

say "[parent description]";

say "[one of][paragraph break]I'm starting to understand how you got into all the places you got into. Not that I judge you or your line of work, of course. [or][stopping][paragraph break]";

record "using the gel" as achieved;

[It's possible, in rare cases, for something to be its own parent: AS+COT -> SCOT -> COT leaves a result that is one of its own earlier ingredients. So we need to account for that: ]

if the item does not proffer the item:

move the item to the repository;

otherwise:

say "Alas, nothing happens.".

To decide what object is home for (item - a thing):

let destination be the holder of the item;

if the item is part of the destination:

let the destination be the location;

decide on destination.

Instead of putting the restoration gel on a naughty-sounding thing:

say "[You] squeeze out a pea-sized quantity of gel and rub it gently onto [--]

No, let me rephrase. [You] clinically and distantly apply some of the restoration gel to an innocent portion of the object in question. [run paragraph on]";

gel-convert the second noun.

Test gel-bug with "tutorial off / show arm to girl / use gel on lock / put gel on lock / gel lock / apply gel to lock / use tube on lock / put tube on lock / apply tube to lock" holding the tube and the arm in the Dormitory.