Counterfeit Monkey — 23 of 292

Emily Short

Release 5

Section 3 - Conversational Greetings

[ The player encounters characters under three basic circumstances (though there can be some overlap between these):

1) The character is manufactured by the player as the result of a letter transformation. (See "Manufactured People".) Manufactured people are not expected to do terribly much, as a rule, though one or two do have a function (the mechanic especially).

2) The character hangs out in a particular room almost all the time. (See "Open Access Characters".)

3) The character is moved on-stage by a scene event and then removed again when the scene is over.

A small handful of characters are one and then the other -- for instance, you can visit Higgate in her office as much as you like until you've triggered off certain essential events with her, after which she reappears only for scene reasons.

In this section we create some actions for saying hello to new characters, and then promptly try to ensure that the player doesn't have to use them much.

Characters who are "alert" will notice and greet the player when he comes into the area, and as this makes them seem more lively and reduces the amount of player effort, it's almost always desirable. We also add a text property so that people can have their own characteristic greetings.]

A person can be alert.

Definition: a person is alarmed if he is alert and he is not the current interlocutor.

Every turn when an alarmed person (called the prospective interlocutor) is enclosed by the location:

try the prospective interlocutor saying hello to the player.

The new default greeting rule is listed instead of the default greeting rule in the report saying hello to rules.

Report saying hello to someone when the greeting type is explicit (this is the new default greeting rule):

say "[You] [one of]say [one of]hello[or]hi[or]hey[at random] to[or]wave at[or]nod to[or]greet[purely at random] [the noun].[paragraph break][greeting of the noun][paragraph break]";

Report someone saying hello to the player:

say "[greeting of the actor][paragraph break]" instead;

A person has some text called the greeting. The greeting of a person is usually "'[one of]Hi[or]Hello[or]Hi there[at random],' [the actor] say[s].".

The greeting of the player is "'Hi,' [you] say."

The report someone saying hello rule is not listed in any rulebook.

The can't greet current interlocutor rule is not listed in any rulebook. The check hailing rule is not listed in any rulebook.

Check hailing (this is the new check hailing rule):

if the current interlocutor is a visible person:

if the current quip is generic-quip:

now the current quip is the greet-quip;

say "[You] [one of]nod[or]wave[or]smile and acknowledge [the current interlocutor][or]say hi[or]return the greeting[at random]." instead;

say already-have instead;

change the noun to a random visible person who is not the player;

if the noun is a person then

say "(addressing [the noun])";

otherwise say "There's no one here but you." instead.

Check saying hello to someone who is not the current interlocutor when the current interlocutor is alert:

say "[The noun] [is-are] already included in the conversation." instead.

Check starting a conversation with clientele about something:

say "They're... busy. At best interrupting them would interrupt their code, and at worst it would make them think [you] [are] a Bureau agent." instead.

Test clientele-bug with "ask parker about slango / ask men about slango" in the Counterfeit Monkey.

Carry out starting a conversation with an eavesdropping person about when the current interlocutor is a person:

say "[You] give [the noun] a look to say [its-their] input would be welcome as well.";

now the reborn command is "ask about [topic understood]";

now sp reparse flag is true instead.

[We do want it to be possible for the player to say "hi" back to a character who has just greeted him if the conversation has just started.]

Check saying hello to a person when the noun is the current interlocutor (this is the new can't greet current interlocutor rule):

if the current quip is generic-quip:

now the current quip is the greet-quip;

say "[You] [one of]nod[or]wave[or]smile[or]say hi[or]return the greeting[at random]." instead;

say already-have instead.

To say already-have:

say "[You] already have the attention of [the current interlocutor][if a person is eavesdropping], not to mention the curiosity of [the list of eavesdropping people][end if]."

Definition: a person is eavesdropping if it is not the player and it is not the current interlocutor and it is enclosed by the location.

The greet-quip is a privately-named quip. The greet-quip is unlisted. The printed name of the greet-quip is "greetings".

Understand "wave to/at [something]" as waving to. Waving to is an action applying to one visible thing.

Sanity-check waving to a person:

try saying hello to the noun instead.

Sanity-check waving to something:

say "[The noun] appear[s] very unlikely to respond." instead.

Test secondaries with "tutorial off / z / say hello / g / ask about paddle / say hello to mark / ask mark about mark / ask mark about the paddle / test customer" in the Drinks Club.

Test customer with "z / ask about maps / say hello to customer / ask customer about maps / say hello to papas / ask papas about maps" holding the map-customer and the papas in Arbot.

Test all-greetings with "all-greet".