Counterfeit Monkey — 277 of 292

Emily Short

Release 5

Section 12 - The Mean Atlantida

The greeting of atlantida-woman is "'I suppose we were bound to meet in person sooner or later,' Atlantida remarks."

Atlantida chat is a scene. Atlantida chat begins when atlantida-woman is in the location. Atlantida chat ends when atlantida-woman is in the repository.

When Atlantida chat ends:

remove the atlantida-woman from play;

move the atlantida-refreshed to the repository.

After examining Atlantida-woman when the Atlantida-woman carries something:

say "Atlantida is carrying [the list of things carried by the Atlantida-woman]."

Rule for writing a topic sentence about the infertile astrologer:

say "[The infertile astrologer] is [one of]idly [or][at random]";

let toy be a random mentionable thing;

if toy is:

-- the stack of files:

say "sifting through [the toy]";

-- the rubber stamp:

say "pressing [the toy] into a few documents";

-- the inlaid desk:

say "admiring the craftsmanship of [the toy]";

-- otherwise:

say "[one of]check out[or]examining[or]toying with[at random] [the toy]";

say ". Her wanderings are gradually moving her closer to us. ";

A description-concealing rule:

if Atlantida chat is not happening:

now Atlantida-woman is not marked for listing;

now restoration-gel rifle is not marked for listing.

Rule for writing a topic sentence about Atlantida-woman:

say "[Atlantida-woman] stands between us and the eastern exit, backlit by sunlight[if the player is gelled and atlantida-woman carries the rifle]. [The rifle] hangs loose in her hand[otherwise if the player is not gelled and the atlantida-woman carries the rifle]. She has [the rifle] trained on our torso[end if]. ";

if Atlantida-woman does not carry the restoration-gel rifle:

say "She dwarfs [the inlaid desk] and all the other furnishings in the room. ";

now the inlaid desk is mentioned;

now the stack of files is mentioned;

now the rubber stamp is mentioned.

Rule for listing exits while looking in Personal Apartment when atlantida-woman is in the location:

do nothing instead.

Atlantida-patience is a number that varies.

After doing something in the Personal Apartment when Personal Apartment is visited and atlantida chat has not happened:

increase atlantida-patience by 1;

if atlantida-patience is greater than 1:

move atlantida-woman to the location.

[atlantida-woman carries the restoration-gel rifle.]

Rule for beat-producing when atlantida-woman is the current interlocutor and atlantida-woman does not recollect gel-shot:

say "Her grip tightens on the [restoration-gel rifle].[run paragraph on]"

When Atlantida chat begins:

[move atlantida-woman to the location;]

pause the game;

set the current interlocutor to atlantida-woman;

queue stop-there as immediate obligatory;

queue gel-shot as postponed obligatory;

[queue how fusion happens as postponed obligatory;]

queue thing-about-democracy as postponed obligatory;

queue summoning-guards as postponed obligatory;

Report taking something which is proffered by the restoration-gel rifle when atlantida chat is happening:

say "We sidle over and casually pick up [the noun] as though we were just curious. Or maybe had an insatiable urge to tidy up." instead.

stop-there is an NPC-directed quip.

The response is "'Don't move, Alexandra, or I'll split you in two.'

A very tall woman with Bureau-blue eyes steps into the room from the east, carrying [a restoration-gel rifle]. Her face is ageless, her mouth full-lipped but proud. We've never met, but [you] recognize her at once[if the player wears the monocle]. The monocle sees her as a fake, a fossilized shellfish[end if].

[Atlantida-woman] moves the rifle a fraction and fires through the portcullis at [the random thing on the pulley]. [pulley-fall]".

It quip-supplies atlantida-woman.

To say pulley-fall:

let target be a random thing on the pulley;

gel-convert the target;

consider the portcullis empty rule;

consider the portcullis fall rule;

say "[run paragraph on]".

Before shooting the restoration-gel rifle with the anagramming gun when the player is not gelled:

say "She sees us moving the gun into position, and our reflexes are slower than hers." instead.

gel-shot is an NPC-directed quip.

The response is "She fires again. The pellet hits us, cold and hard, in the shoulder. It stings like hell and for a moment I think our clavicle is broken. [You] put our hand over the wounded spot.

Our hand.

Atlantida lowers the rifle, surprised. 'Fused,' she says. 'Isn't that interesting. And so recently, too. If the gel rifle won't separate you, nothing will.' She smiles, not warmly. 'Pity. You would have been easier to deal with separately. Cold Storage for Andra, house arrest for Alex.'"

It quip-supplies atlantida-woman.

summoning-guards is an NPC-directed quip.

The response is "[if the restoration-gel rifle is visible and the restoration-gel rifle is not carried by Atlantida-woman]Atlantida real[ize]s that [the restoration-gel rifle] is now a couple of me[ter]s away from her. [otherwise]'And now it's time for you to go,' Atlantida says. [end if]

She presses a button on something in her hand. Far away, a high-pitched bell rings.

'Did you have anything else you wanted to ask me? I so rarely get to talk with ordinary citizens. Only ones with clearance, and those about to go into Cold Storage. A last interview with Saint Peter.'"

Instead of saying yes when the player carries the restoration-gel rifle and the current quip is summoning-guards:

say "'Oh, I have lots of questions,' [you] say.";

try shooting atlantida with the restoration-gel rifle.

Instead of saying no when the player carries the restoration-gel rifle and the current quip is summoning-guards:

say "'Not really,' [you] say.";

try shooting atlantida with the restoration-gel rifle.

not-long-now is an NPC-directed quip.

The response is "'I see,' says Atlantida. 'You have the rifle. Clever, but do think. You might do some damage with that thing, but you won't escape. So why hurt anyone unnecessarily?'"

Waiting for guards is a scene. Waiting for guards begins when atlantida-woman recollects summoning-guards.

Waiting for guards ends in capture when the time since waiting for guards began is 2 minutes.

Report waiting during waiting for guards:

say "[one of]I don't think we have much time left[or]Time is slipping past, time when we could be doing something[or]It can't be much longer now[at random]." instead.

Waiting for guards ends in diversion when atlantida-woman is not visible.

When waiting for guards ends in capture:

say "There are noises in the next room, and a moment later a couple of All-Purpose Officers burst into the room, gel rifles and real rifles drawn.

'You're slow,' Atlantida says, seating herself on the ridiculous bed. 'I thought we had trained for this eventuality.'

The officer nearest the door turns red. 'This has been a busy day, madam,' he says. As though she were a queen.";

end the story saying "We have been caught".

Before shooting the atlantida-woman with the rifle:

if the player is not carrying the rifle:

try taking the rifle;

say "Her eyes follow the gesture. 'Don't you dare, you little traitor,' she says. 'I have been your mother, your father, your waking up and your going to sleep, your teachers and your lovers and your friends. I am the integrity of this island. Change me and you change Atlantis forever.'

'Maybe it's time,' I say. 'Maybe part of the business of democracy is having the arguments[--]'

You don't let me finish. [run paragraph on]"

Instead of showing something to Atlantida-woman:

say "You know better than to give away any unnecessary information, any advantage."

Rule for quip-introducing how fusion happens:

say "Fused? We should be two pieces by now. Maybe she has an explanation? But you seem to be focused on her gun hand. How can you be so calm?";

strip how fusion happens from the table.

how fusion happens is a questioning quip. The comment is "'Fused?' [you] repeat.".

Understand "fused" or "what has happened" or "what happened" or "happened" or "chance" or "explanation" or "separation" or "us" or "ourselves" or "stuck" or "gel rifle" as how fusion happens.

It mentions yourself.

The response is "'Sometimes a synthetic person gets broken,' Atlantida says. 'Forced into a choice [if the library message person is second person]he[otherwise]she[end if] would never have made on [if the library message person is second person]his[otherwise]her[end if] own. Impossible to separate because you aren't two whole people any more.'".

It quip-supplies Atlantida-woman.

It directly-follows gel-shot.

thing-about-democracy is an NPC-directed quip.

The response is "Atlantida smiles with half a mouth. 'You've arrived on a difficult day. In the ordinary course of things, I keep things quiet: the spirit of democracy, but none of the sordid wrangling and bribes and corruption and compromise. It's only when the spirit of the island itself is threatened, that we have to resort to such extreme measures[casually queue more-about-democracy][if the infertile astrologer is visible].'

The infertile astrologer sidles closer to us, smiling and making hand signs that I think are supposed to represent Aries. Old bat.[otherwise].'[end if]"

After examining the infertile astrologer when Atlantida-woman does not recollect thing-about-democracy:

say "She's investigating the room and muttering to herself, but Atlantida seems to be ignoring her for the most part. She'll have worked her way over by us soon."

After examining the infertile astrologer when Atlantida-woman recollects thing-about-democracy:

say "She's standing within arm's reach now."

Instead of putting restoration gel on the infertile astrologer when Atlantida-woman does not recollect thing-about-democracy:

say "The astrologer is still a little too far away to reach. She's moving towards us, though. If we wait, perhaps..."

more-about-democracy is an NPC-directed quip.

The response is "'Do you think the protesters would feel happier if there had been a citizen referendum where their position had been voted down? The outcome would have been just the same, but they would feel much more responsible for it; surely an unpleasant position for them to be in, considering their moral objections.'"

whether the protesters feel the same way is a questioning quip. The comment is "'What about the protesters?' [you] ask. 'They don't like your policy. Are you sure you're really representing the spirit of Atlantis, or have you gone some other way of your own?'".

It mentions security, bureau.

The response is "Atlantida shrugs off our question. 'A vocal minority. Most people are content to keep what they have. Imagine the chaos if everyone had free access to the Bureau's complete range of letter tools, and if there were no laws about how to use them[casually queue more-about-democracy].'".

It quip-supplies Atlantida-woman.

It directly-follows thing-about-democracy.

Understand "if" as whether the protesters feel the same way.

Carry out Atlantida-woman discussing gel-shot:

now the player is gelled.

Carry out taking the anagramming gun: [Once we've decided we need it, we need to keep carrying it]

now the anagramming gun is essential.

Before putting restoration gel on the infertile astrologer:

if Atlantida-woman does not recollect summoning-guards:

queue summoning-guards as immediate obligatory;

otherwise:

queue not-long-now as immediate obligatory.

Instead of throwing the tub at the Atlantida-woman:

say "We fling the tub at her. Unfortunately, the gel is sticky enough that it doesn't, as I had sort of hoped, spill out all over her. She dodges, then hurls it back at us [--] and she has better aim[casually queue anti-gel comment]."

Instead of going somewhere in the presence of Atlantida-woman:

say "'I don't think so,' says Atlantida. As she's physically about twice our mass, I think she'll win this one."

Every turn when atlantida-woman is carrying something (called target) which is not the restoration-gel rifle:

try Atlantida-woman dropping the target.

Report atlantida-woman dropping the infertile astrologer:

say "The infertile astrologer falls awkwardly to earth and looks around in confusion[casually queue cutting-remark]." instead.

cutting-remark is an NPC-directed quip.

The response is "'Oh, bravo,' says Atlantida. 'Could you possibly have made a less useful ally?'"

Before putting restoration gel on Atlantida-woman:

say "We dab a bit on our finger and approach, but she is far too large, far too spry. She catches our wrist and forces us aside, until the gel is harmlessly absorbed into our own skin[casually queue anti-gel comment]." instead.

anti-gel comment is an NPC-directed quip.

The response is "'Oh, no, my dear,' Atlantida says. 'They could remake me, but it wouldn't be the [i]same[/i] me, would it? It would be some new construct. The Atlantida of today. And that's not the way to a consistent policy, is it?'"

Check shooting Atlantida-woman with the anagramming gun:

casually queue anti-anagram comment.

anti-anagram comment is an NPC-directed quip.

The response is "'I'm not so vulnerable,' she remarks. 'They chose my name carefully.'"

that the outside world matters is an unlisted informative quip. The comment is "'We have important things to do in the outside world. Atlantis can't keep all of its power to itself.'".

It mentions yourself.

The response is "'And do you know what would happen if Atlantean power were to spread beyond our borders? The rest of the world would become just like us. The incentive to wipe out every diversity, every variation of language would be too great.'".

It quip-supplies Atlantida-woman.

how she justifies cold storage is an unlisted questioning quip. The comment is "'How do you excuse putting people in Cold Storage? It's a human rights violation.'".

It mentions crime, legislation.

The response is "Atlantida makes a motion as though brushing away an insect. 'The laws of Atlantis are special. They keep us strong; they keep the rest of the world safe.'".

It quip-supplies Atlantida-woman.

[Carry out shooting the anagramming gun at something in the presence of ]

[Test oracle with "tutorial off / autoupgrade / unmonkey / wave h-remover at power chord / open tub" in the Oracle holding the anagramming gun and the power chord and the pastis and the tub.]

[Her reactions to gunning down other objects...]

After shooting something with the anagramming gun in the presence of atlantida-woman when the detritus is the sickest offal :

queue is-it-commentary as immediate obligatory;

continue the action.

Is-it-commentary is an NPC-directed quip.

The response is "She makes a disgusted face. 'I hope you're planning to clean that up.'"

Instead of Atlantida-woman discussing is-it-commentary when atlantida-woman carries the restoration-gel rifle and the sickest offal is visible:

say "She looks annoyed and shoots the offal. ";

gel-convert the offal;

say "[one of]'As political commentary, that wasn't very well-conceived.'[or]'I have plenty of ammunition in this rifle,' she remarks.[or]This time she doesn't bother to comment.[stopping]".

After shooting something with the anagramming gun in the presence of atlantida-woman when the detritus is the intaglio-pins:

queue not-so-bad-pins as immediate obligatory;

continue the action.

not-so-bad-pins is an NPC-directed quip.

The response is "[one of]'Hm,' Atlantida comments, remarking the intaglio pins. 'Makes a change from the paintings, I suppose. I don't mean to complain [--] they did go to quite some effort over these chambers [--] but one gets tired of the same scenery after a while, don't you think?'[or]Her glance flickers towards the pins but she doesn't seem to think they deserve any further remark.[stopping]"

After shooting something with the anagramming gun in the presence of atlantida-woman when the detritus is the kind ladies :

queue barely-acknowledges as immediate obligatory;

continue the action.

barely-acknowledges is an NPC-directed quip.

The response is "Atlantida's glance flickers towards the ladies, but she barely acknowledges them."

Instead of atlantida-woman discussing barely-acknowledges when atlantida-woman carries the restoration-gel rifle and the kind ladies are visible:

say "[one of]'Is [--] is there anything I could do to assist?' asks one of the ladies. 'It looks as though you two are having a bit of a disagreement. Maybe if we all sat down together and talked about what we are feeling [--]'[or]This time one of the ladies offers a muffin.[no line break][or]The ladies back nervously against the wall, except one who says, 'I still think we could work this out.'[no line break][or]The ladies are cowed but regard us with mute hope.[no line break][stopping]

Atlantida [one of]rolls her eyes and fires the weapon, hitting the lady speaking neatly in the middle of the forehead. She doesn't seem much bothered by the idea that these fake people are essentially her own kind, really[or]casually shoots the speaker again[or]picks off the ladies with her rifle[stopping]. [run paragraph on]";

gel-convert the kind ladies.

[And some ways of attacking her...]

Sanity-check going east in the presence of atlantida-woman:

say "[You] would have to get through her first." instead.

After attacking atlantida-woman with something when Atlantida-woman carries the restoration-gel rifle:

if the second noun is proffered by Brock:

continue the action;

if the second noun is proffered by something which is not the second noun:

say "Atlantida raises the rifle and fires with certain aim before the blow has a chance to land. [run paragraph on]";

gel-convert the second noun;

otherwise:

say "[You] leap forward and slash with [the second noun][one of]. She parries the blow with the body of [the restoration-gel rifle]. It doesn't even look damaged[or]. She wards us off with the rifle[or]. She dodges[at random]."

Report attacking atlantida-woman with the leaf:

say "[You] wield the leaf like a dagger[one of] and slice across her arm, drawing blood. She recoils, angry but not deterred[or]. This time [you] don't manage to land another blow[stopping]." instead.

Report attacking atlantida-woman with something:

say "[one of][You] swing [the second noun] at her, but can't quite reach. She's keeping her distance[or]Closing some of the distance, [you] try a slash of [the second noun]. She leaps backward[or][You] lunge with [the second noun], but she dodges[cycling]." instead.

Instead of throwing something at atlantida-woman:

if the noun is r-abstract:

say "[The noun] wouldn't make much impact, other than perhaps notionally. And Atlantida doesn't look like she's open to persuasion, even if the concept of [the noun] were one that carried weight in this situation.";

otherwise if the noun is floppy and the noun is long:

say "[The noun] make[s] a poor projectile and land[s] back near our own feet.";

move the noun to the location;

otherwise if the noun is long:

say "[You] cast [the noun], javelin-like, at Atlantida's heart, but [one of]she dodges[or][you] undercalculate the amount of force required and [the noun] clatter[s] to the ground instead[or]miss[at random]. Her expression is disdainful.";

move the noun to the location;

otherwise if the heft of the noun is less than 3:

let random-destiny be a random supporter which is in the location;

say "[You] fling [the noun] at Atlantida, but [one of][it-they] bounce[s] off unexcitingly and land[s] on[or]with a swipe of her arm she deflects [it-them] to[at random] [the random-destiny].";

move the noun to the random-destiny;

otherwise if the heft of the noun is greater than 3:

say "[The noun] [is-are] too heavy for us to throw at all effectively.";

otherwise:

say "[You] chuck [the noun] at Atlantida. [It-they] strike[s] her hard enough to elicit an outraged 'Oof!', but that doesn't seem to have substantially impaired her."

Understand "gun hand" as the restoration-gel rifle when the restoration-gel rifle is carried by Atlantida-woman.

Test oracle with "tutorial off / autoupgrade / unmonkey / load gun / wave h-remover at power chord / open tub / look / x paintings / x charts / x fable / gel paperweight / gel fable / look up 1942 in cabinet / look up 1982 in cabinet / look up 1962 in cabinet / look up 1958 / look up 1964 / look up 2003 / look up 1983 in cabinet / x paper / x weight / get weight / e / e / e / put pastis in bucket / go to workshop / plug in cord / go to surveillance / d / get counter / go to workshop / put counter and weight on dais / turn switch / pull lever / get counterweight / go to tunnel / put counterweight on hook / pull counterweight / e" in the Oracle holding the anagramming gun and the bullets and the power chord and the pastis and the tub.

Test missiles with "establish / throw rock at Atlantida / throw paper at atlantida / throw plans at atlantida / throw sword at atlantida / throw tub at atlantida / throw pans at atlantida / throw ire at atlantida" holding the rock and the page and the sword and the secret-plans and the iron-pans and the ire.

Test attacks with "establish / hit atlantida with sword / hit atlantida with foil / hit atlantida with stick / hit atlantida with sill / hit atlantida with leaf / hit atlantida with slat / hit atlantida with track / hit atlantida with warm rods / hit atlantida with wand batch / hit atlantida with swordstick / hit atlantida with crosspiece" holding the sword and the foil and the stick and the sill and the leaf and the slat and the track and the warm rods and the wand batch and the swordstick and the crosspiece.