Counterfeit Monkey — 278 of 292

Emily Short

Release 5

Section 13 - Scene Interlude with Guards

Sanity-check going through the tall window when Atlantida-refreshed is off-stage:

if library message person is second person:

say "[You] could do that. [You] could climb out that window and not look back. It would be faster, easier, unquestionably safer. But what about the people we're leaving behind? What about my father and Professor Higgate? What about the protesters who got arrested today?

We'll only know they're safe if we leave this island with a new, improved Atlantida. Someone the Bureau will have to listen to. The one they were afraid of creating. One who will put power back in the hands of the citizen referendum.

So you tell me how it's going to be. Are you going to stay and see to things? >>";

if the player consents:

extend scene time;

say "[line break]That's what I thought." instead;

otherwise:

say "[line break]Should've known. Well, I suppose I can't stop you.";

now the description of the newspaper is "It's the Chard-Farmer's Daily from Atlantis. It describes in glowing terms the delightful festival that was Serial Comma Day. There is no reference at all to the protests and mass depluralization, much less to anything that might have happened to my father or Professor Higgate.";

otherwise:

extend scene time;

say "Maybe you would do that. I've got a little more on the line, and you've lost most of your vote, so we're going to do things my way. We're going to reinstate Atlantida in her new form. Someone the Bureau will have to listen to. Someone who will be merciful to Brock and Higgate and all those protesters, who'll put the power back in the hands of the citizen referendum." instead;

[At the point where we decide not to escape, we want to give the player an extension on time to complete the transformation of Atlantida to make sure there's no loss.]

To extend scene time:

while the number of filled rows in the Table of Guard Warnings is less than 10:

choose a blank row in the Table of Guard Warnings;

now description entry is "[one of]Strangely quiet out there[or]No signs of anyone coming for us quite yet[or]The lull continues[at random]."

Further guards is a scene. Further guards begins when atlantida chat has ended and the time since atlantida chat ended is 2 minutes.

When further guards begins:

say "There's a distant sound of movement. Someone is looking for us."

Further guards ends in escape when the location is Precarious Perch. Further guards ends in imminence when guard-imminence begins.

Report waiting during further guards:

say "[one of]I don't think we have much time left[or]Time is slipping past, time when we could be doing something[or]It can't be much longer now[at random]." instead.

When further guards ends in escape:

say "Whoever is looking for us, we should be out of their way now."

Every turn during Further Guards:

repeat through the Table of Guard Warnings:

if there is a description entry:

unless the description entry is "":

say "[description entry][paragraph break]";

blank out the whole row;

break.

Table of Guard Warnings

description
""
""
""
""
""
""
""
""
""
"Maybe those noises we heard earlier were nothing. It's quiet now."
"Our ears are straining for something far away."
""
"The silence is eerie."
""
"A distant alarm bell is ringing."
""
"The faint ringing continues."

Guard-imminence is a scene. Guard-imminence begins when the player can see the programmable dais and the player can see the atlantida-shellfish. Guard-imminence ends in postponement when the player can see atlantida-refreshed. [The design principle here is that the player is on a timer, but every time he succeeds at moving the plot forward, that timer is stopped and a new one starts. So it's never possible to fail a late-stage scene because of having taken too long in an earlier stage.]

Every turn during Guard-imminence:

repeat through the Table of Severe Guard Warnings:

if there is a description entry:

unless the description entry is "":

say "[description entry][paragraph break]";

blank out the whole row;

break.

Table of Severe Guard Warnings

description
"I definitely hear footsteps. And voices."
""
""
"There's a percussive explosion sound from the west."
""
"Banging. More percussion."
""
""
"Whoever is coming, they're not trying to be stealthy."

Guard-imminence ends in capture when the number of filled rows in the Table of Severe Guard Warnings is 0.

When guard-imminence ends in capture:

say "There are noises in the next room, a couple of All-Purpose Officers burst into the room, gel rifles and real rifles drawn.

'Where is she?' asks a commanding voice. A man we haven't met comes in and surveys the area. 'What have you done with Atlantida?'

We say nothing.";

end the story saying "We have been caught".

Test almostlast with "tutorial off / load gun / put counterweight on hook / open tub / open portcullis / go through portcullis / x files / a cold storage / look / shoot anagramming gun at gel rifle / look / gel astrologer / shoot gel rifle at atlantida" in the Tunnel holding the anagramming gun and the bullets and the tub and the counterweight.

Test lastmeeting with "tutorial off / open tub / x files / a cold storage / look / shoot anagramming gun at gel rifle / look / gel astrologer / shoot gel rifle at atlantida" in the Personal Apartment holding the anagramming gun and the tub.