Counterfeit Monkey — 55 of 292

Emily Short

Release 5

Section 2 - Propping Doors

Wedging relates one thing to one door. The verb to wedge (it wedges, they wedge, it wedged, it is wedged) implies the wedging relation.

Propping it with is an action applying to one thing and one carried thing.

Understand "prop [something] with [something preferably held]" or "prop up/open [something] with [something preferably held]" or "prop [something] up/open with [something preferably held]" as propping it with. Understand the commands "wedge" or "jam" or "block" or "support" as "prop".

Understand "put [something long] in/into/under/beneath [a door]" or "insert [something long] in/into/under/beneath [a door]" or "prop [something long] in/into/under/beneath [a door]" as propping it with (with nouns reversed).

Check propping something which is not a door with something:

say "Propping is something best done to doors." instead.

Definition: a thing is bendy:

if it is strong:

no;

if it is long:

yes;

no.

Check propping something with a bendy thing:

say "[The second noun] [is-are] long enough, but too flexible to provide much support against the springs of [the noun]." instead.

Check propping something with something which is not long:

say "[The second noun] [is-are] not long enough to prop [the noun] very effectively";

if the second noun is strong:

say ", though at least [it-they of second noun] [is-are] fairly stout." instead;

else:

say ", and even if [it-they of second noun] were, [it-they of second noun] wouldn't hold up against the pressure of the springs." instead.

Check propping something which is wedged by something (called the existing impediment) with something:

say "[The noun] [is-are] already propped open by [the existing impediment]." instead.

Carry out propping a door with something:

now the noun is open;

move the second noun to the location;

now the second noun wedges the noun;

Report propping a door with something:

say "[You] prop [the noun] open with [the second noun]."

Carry out taking something which wedges something:

now the noun does not wedge anything.

A dangerous destruction rule for something which wedges something (called item):

now the item is not wedged by anything.

Test propping with "open tub / d / u / open door / prop door with twig / prop door with wig / prop door with plans / prop door with fish / look / prop door with stick / d / u / wave t-remover at stick / gel sick / prop door with stick / d / wave t-remover at stick" holding the tub and the stick and the twig and the wig and the secret-plans in the tin hut.