Counterfeit Monkey — 100 of 292

Emily Short

Release 5

Chapter 2 - Indoor Areas

Section 1 - Cinema

The Cinema Lobby is north of Church Forecourt. It is indoors. "This is a small, one-screen theater. [one of]The seats are not comfortable and the screen is not large. The projector is old. The management is lazy. No food is served.

On two occasions, the film I was watching burst into flames while it was being shown.

Despite these handicaps, it maintains an active and interested clientele simply by virtue of content: a wide variety of foreign films that, though meticulously dubbed into flawless California-accented English, nonetheless carry that slight tang of the forbidden.

[or][stopping]Evidently the next showing is not for a little while yet, because there are no patrons in sight."

Instead of going in when in Cinema Lobby:

try going west.

Rule for listing exits when in Cinema Lobby:

if looking, do nothing;

otherwise say "There is of course the exit to the south; the screening room itself is west."

The ticket-taker is an alert man in the Cinema Lobby. "[The ticket-taker] waits just west of us, at the entrance to the screening room, ready to take tickets."

The description of the ticket-taker is "Not one of this country's best and brightest, but he seems good-natured."

Understand "young" or "man" or "ticket taker" or "taker" as the ticket-taker.

Rule for writing a paragraph about the ticket-taker when the ticket-taker is not the current interlocutor:

set the current interlocutor to the ticket-taker;

if the ticket-taker knows allowed-in-movie, say "'Yo,' says the [ticket-taker] as [you] come in.";

otherwise say "'Ticket,' says the [ticket-taker] automatically.";

have the parser notice the ticket-taker;

now everything held by the ticket-taker is mentioned.

Instead of going to the Screening Room when the ticket-taker does not know allowed-in-movie:

carry out the describing path activity with the player;

if the ticket-taker is not in the location, continue the action;

set the current interlocutor to the ticket-taker;

queue hang-on-there.

The Screening Room is west of Cinema Lobby. It is indoors. "[if the player recollects what the movie seems]'Red'[otherwise]Whatever is scheduled for later showing[end if] has not started yet, and is probably not destined to start for some time; at any rate,[unless the project is switched on] the [film screen] is blank and[end if] no audience has yet assembled."

Instead of waiting in the Screening Room:

if the reel is in the projector and the projector is switched on:

make no decision;

say "[one of]A little time passes, but I don't think the movie's likely to start for quite some time.[or][You] haven't got time to wait for the show to begin.[stopping]".

Instead of listening to the Screening Room:

say "The thick walls and solitude make for an especially thick and syrupy silence, as though the rest of the world didn't exist at all."

The film screen is scenery in the screening room. Understand "show" or "movie" as the film screen. The printed name is "screen". The description is "[if the reel is in the projector and the projector is switched on]The screen flickers black and white[otherwise if the projector is switched on]The white beam from the projector illuminates it, but no movie is showing[otherwise]The screen is empty: nothing is yet being shown. It is also very very small by modern cinema standards[end if]."

The seats are an enterable supporter in the Screening Room. The seats are scenery. The description is "In an age of stadium seating and theater chairs that resemble home recliners, these don't even have the usual old-fashioned red plush. They are hard wooden seats such as might be found in a puritanical schoolroom." Understand "row" or "rows" or "seat" or "seating" or "chairs" or "chair" as the seats.

Instead of looking under the seats when the backpack is in the Screening Room:

say "I've already located the backpack, right where I left it."

The scent-description of the seats is "a mixture of wood lacquer and popcorn grease".

The backpack is in the Screening Room. "My [backpack] is stowed under a seat in the third row from the back." Understand "pack" or "rucksack" or "backsack" as the backpack.

The backpack is wearable and essential.

It covers the torso-area.

The introduction of the backpack is "I figured that it would be undisturbed there for a couple of hours, in the dark and out of sight, and if anyone found it they would probably turn it in to Lost and Found. But it is a big relief to find it still there."

The backpack is a player's holdall. The description of the backpack is "Mine: a little bit worn, but capacious. It doesn't have any identifying marks on it, and I thought a brand-new bag would look more suspicious[if the backpack is open]. It currently gapes open[else]. It's closed[end if]." The backpack is openable and closed and transparent.

The backpack contains a flash drive. The description of the flash drive is "This is it: all my notes; the syllable-and word-generating programs from which I built my language vocabulary; the lexicon and pronunciation guide and grammatical descriptions.

And then there's the research to support the product: citations; copies of journal articles and scans from books; contact information for people in the outside world I think could help me.

It's everything I've been working on for the last three years."

Carry out taking the flash drive:

complete "Get my backpack from the cinema";

record "retrieving the backpack" as achieved.

Carry out taking something which encloses the flash drive:

complete "Get my backpack from the cinema";

record "retrieving the backpack" as achieved.

The flash drive is essential.

[ The projection booth is here chiefly for easter egg purposes: if the player (much later on) manages to create the abstract LEER, run it through the mirror, and bring the resulting REEL back to the projection booth, the result is this curious movie -- an achievement reward. ]

The Projection Booth is north of Screening Room. It is indoors. "The booth is small and lined with [grey-carpet]. It smells faintly of hot dogs."

The grey-carpet is scenery in the Projection Booth. The printed name is "grey carpet". Understand "gray" or "grey" or "carpet" as the grey-carpet. The description is "In this dim light it's hard to give the carpet too exact an inspection, which I imagine is just as well."

Instead of smelling the Projection Booth:

say "The ghost of hot dog and relish lingers in the air. It's mildly nauseating."

The jotter is a notepad in the Projection Booth. "[A jotter] is propped up next to the projector." The description is "It's a little spiral-bound notebook, the kind reporters in old movies carry. It's full of notes: running times of movies. Numbers of people in the audience. Who clapped during potentially subversive scenes. Who arrived in a group of more than three."

The allowed-pens of the jotter is { pen, pens }.

The memo of the jotter is "Red: audience 14. FM couple. MM couple. M in raincoat. FFFFF group. F. MF. M.".

Rule for writing a topic sentence about the jotter when the projector is mentionable:

say "[A jotter] is propped up next to [the projector]."

The projector is a container in the Projection Booth. It is fixed in place. "[A projector] has been set up facing the [film screen][if the reel is in the projector] and [a reel] threaded into it[end if]." The description of the projector is "It's an old-fashioned film projector[if the reel is in the projector], with [a reel] of film inserted[otherwise], with a spot to hold [a reel] of film[end if]. The lens points at the screen." Understand "lens" as the projector.

The projector-switch is a device. The projector-switch is part of the projector. The printed name of the projector-switch is "projector switch". Understand "switch" or "projector switch" as the projector-switch.

Sanity-check switching on the projector:

try switching on the projector-switch instead.

Sanity-check switching off the projector:

try switching off the projector-switch instead.

Report switching on the projector-switch when the reel is not in the projector:

say "The light comes on, but nothing plays." instead.

Carry out switching on the projector-switch when the reel is in the projector:

now the reel position of the reel is 1.

Report switching on the projector-switch when the reel is in the projector:

say "[You] flip the switch. [The projector] comes to life with a hum. There's the usual flickering of light and dust, and then a black and white movie begins to play." instead.

Understand "movie" or "black and white" as the reel when the reel position of the reel is greater than 0.

The reel has a number called reel position.

[The reel here is a little bit like the tale, in that it produces a partially randomized story. This time, however, instead of going for a plot, we juxtapose a series of unexplained images and leave it up to the reader to try to imagine a connection between them -- a fires in the desert approach a la Wilmot's End, to borrow the language of Echo Bazaar.

The intention is to suggest an encounter with a slightly inexplicable film that deals with emotional reactions towards the Atlantean threat and all that goes with it.

The filmmaker is Lucius Quagmire, whose manifesto can also be found in the Aquarium Bookstore by the determined searcher.]

Every turn when the reel is in the projector and the projector-switch is switched on (this is the movie advancement rule):

record "Lucius Quagmire award for viewing unusual films" as an achievement;

if the location is Projection Booth or the location is Screening Room:

say "[cartoon event for reel position of the reel]";

increase the reel position of the reel by 1;

if the reel position of the reel is greater than 4:

now reel position of the reel is 1;

now the projector-switch is switched off. [if we go away for a while and come back, we'll find that the story has progressed in our absence]

Instead of examining the reel when the reel is in the projector and the projector-switch is switched on:

follow the movie advancement rule.

To say on screen:

say "[one of]On screen,[or]On the screen,[or]In the movie,[or]In the picture,[or]As we watch,[at random]".

To say harmless event:

say "[one of][viewpoint character] is painting an easter egg with meticulous care[or]a little blonde girl romps through a field carrying a basket[or][viewpoint character] is making a fuss over a white rabbit in a cage[or]a kneeling priest is placing an egg under one of the pews of his church[or]three little boys are throwing eggs at one another[or][viewpoint character] is vigorously squeezing a hen, who does not appear to have done anything to deserve it[or]church bells are ringing in the spire of a Gothic church[or]a lady with white gloves is turning over and over an enamel egg studded with gemstones[or][viewpoint character] dips a pastry brush into a dish of yolk[at random]".

To say foreboding event:

say "[one of]a man with a snub-nosed pistol is stealing two eggs from a cleric[or]the camera zooms in close on an egg. There is a sound of ticking[or]two men circle each other warily on a stone bridge, built across a dangerous ravine. One of them wears a badge in the shape of a rooster. The other has a giant A stitched to his coat[or]a plane buzzes low to the ground over a peaceful-looking farm. A man parachutes out, lands, and sneaks into the barn. He is carrying a number of pamphlets in English[or]customs officials are unpacking sawdust from a box, revealing a number of uniquely decorated eggs. One of them snaps an order abruptly at the other. Both look alarmed. In close-up, we see tiny writing on the eggs[or]a nurse in uniform counts out glass ampules of clear liquid. Her fingers tremble. She sets the ampules on a table next to a figurine of a white rabbit[or]a girl in white gloves sits down on a church pew and folds her hands to pray. As she does so, the flowers on the altar wilt and turn black[or][viewpoint character] kneels in the dirt, burying eggs in a row as though they were tulip bulbs[at random]".

To say atmospheric event:

say "[one of][viewpoint character] watches as an egg begins to chip from the inside. Something is trying to get out[or]the camera closes and holds for a long time on a glass jar of pickled eggs. Finally a young boy's hand reaches in and extracts one of the pickles. The rest of the boy is not shown[or]a dead rabbit on a string hangs from the tree. The shot holds there for a long period. Wind rustles in the grass[or]a woman clings to the lapels of a sharply-dressed gentleman. He pushes her away. She takes off a brooch shaped like a rooster and flings it at his feet. He picks it up and slowly pins it to his tie[or]an old man lies on his deathbed, two generations of family members gathered around him. A bird lands on the windowsill outside. It lays a spotted blue egg[or]a pair of eggs sizzle in a frying pan for what feels like an entire minute, before a film hand descends to remove them to a plate[or][viewpoint character] sits skinning a brown rabbit. The film lingers over the separation of skin from flesh, and the glassy look in the dead rabbit's eyes[or][viewpoint character] finds an Atlantean flag [--] one of the old style from before the second World War [--] and tears it into strips[at random]";

To say climactic event:

say "[one of]angry villagers pelt a plane with rotten eggs while a man in [--] is that Atlantean uniform? [--] cowers away from their wrath[or]a country church explodes from the inside, the stained glass blowing out in all directions. Beleaguered peasants watch with dumb incredulity. A small girl bleeds[or][viewpoint character] digs, manic and desperate, in a graveyard, while more and more villagers come to watch. At last they discover something at the bottom of the hole. Everyone draws back, appalled, but the film does not show us what they are seeing[or][viewpoint character] runs into a burning house and remains there while the fire burns higher and higher, only to return with a book in a worn black binding. From the notches cut into the edges of the page, it appears to be a Bible or a dictionary[at random]";

To say denouement event:

say "[one of][viewpoint character] applies restoration gel to an easter egg, which turns into a young boy[or]citizens erect a stone monument of a rooster, on a high platform overlooking the sea. Then [viewpoint character] garlands the monument with flowers[or]a priest reads the service over a casket[or]half a dozen children seated on a porch eat fried eggs from the same pan. They have a wild-eyed look, which [viewpoint character] seems to find frightening or sad[at random]";

The viewpoint character is indexed text that varies.

To say first arrival:

say "The scene opens on [a viewpoint character][one of] seated in the sunshine[or] reading a newspaper[or] kneeling in the dirt outside a farmhouse[or] walking across a field[or] doing some shopping at a farmer's market[or] carrying a cage containing a rabbit[or] putting eggs into a basket[or] purchasing a set of paints[or] speaking earnestly if incomprehensibly to camera[or] reading aloud from a small black book that looks much battered[or] peering into a cracked mirror[or] drawing one finger across a map of the Mediterranean[or] cutting letters from a newspaper with a pair of nail scissors[or] gathering a clump of grubby carrots and washing them at a pump[at random]";

To say cartoon event for (N - a number):

if N is 1:

say "A jolly title card comes up, which reads '[one of]Les oeufs de Pâques[or]Ostereier[or]Huevos de pascua[or]Uova di Pasqua[or]Pazko-arrautzak[at random]'.";

now the viewpoint character is "[one of]a man in a black uniform[or]a woman in a chic blue hat[or]a farmer with calloused hands[or]a little blonde girl[or]a nurse in wartime uniform[or]a priest[or]a skinny spinster[or]a husky-voiced housewife[or]a teenaged boy[at random]";

say "[line break][first arrival]. Afterward, [one of][harmless event][or][atmospheric event][at random].";

if N is 2:

say "[on screen] [one of][foreboding event][or][harmless event]. [paragraph break]Then [foreboding event][or][atmospheric event]. [paragraph break]Next [foreboding event][at random]. [one of]The dialogue is rapid, foreign, and distorted by poor film quality and the passage of time[or]It's impossible to make out what's being said, but the music is melancholy, played on a distressed fiddle[or]The soundtrack has so degraded that the words are incomprehensible, but there is a backing tune of young children singing[at random].";

if N is 3: [conclusion]

say "[on screen] [climactic event].

Finally, [one of][atmospheric event][or][denouement event][at random].";

if N is 4:

say "The credits come up on the screen. Not a single one of these names is suitable for daily use on the island. After three cards of names, a final note comes up reading, DISTRIBUTED UNDER THE HAND OF LUCIUS QUAGMIRE. FOR THE DISTURBANCE OF MEANING.

The film ends and the projector goes dark.";

Check inserting something into the projector:

if the noun is not the reel:

say "The projector can only really show reels of film." instead;

if the projector-switch is switched on:

try switching off the projector-switch;

Sanity-check putting the reel on the projector:

try inserting the reel into the projector instead.

Understand "thread [reel] on/onto [the projector]" as inserting it into.

Understand "mount [reel] on/onto [the projector]" as inserting it into.

Understand "show [reel] on [the projector]" as showing it on. Showing it on is an action applying to one carried thing and one thing.

Check showing something which is not the reel on the projector:

say "[The noun] [is-are] not a reel of film." instead.

Check showing the reel on something which is not the projector:

say "[You] really need a film projector for that." instead.

Check showing something which is not the reel on something which is not the projector:

say "I could understand if you were trying to show film on a projector, but that suggestion doesn't make much sense to me." instead.

Check showing the reel on the projector when the reel is not in the projector:

try inserting the reel into the projector;

if the reel is not in the projector:

stop the action.

Check showing the reel on the projector when the projector-switch is not switched on:

try switching on the projector-switch;

if the projector-switch is not switched on:

stop the action.

Test projection with "tutorial off / put reel on projector / turn on projector / take reel / mount reel / take reel / thread reel / take reel / show reel / show reel on projector / s / z / z / n" holding the reel in the Projection Booth.