Chapter 5: The Viewpoint Character
5.1. The Human Body

By default, Inform gives the player character (and every other person) a simple unitary body, one without hands or feet or any other defined parts. In many games this is adequate; but in others it is not enough, and we may want to endow all people with some more specific physical features, as in

A face is a kind of thing. A face is part of every person.

Once we've done this, we may invite ambiguities if the player types LOOK AT FACE; it is this challenge that is addressed in The Night Before.

Our other examples have more specialized effects. Pink or Blue demonstrates a way to let the player choose a gender at the start of play: this will mostly be interesting if the rest of the game makes some use of the player's choice. Since that example is written expressly to demonstrate included Inform 6 code, however, we may find it more congenial to generalize from the more flexible Baritone, Bass.

rBGH gives him a random height and then uses this to determine how the room should be described around him.


44
*** Example  The Night Before
Instructing Inform to prefer different interpretations of EXAMINE NOSE, depending on whether the player is alone, in company, or with Rudolph the Red-nosed Reindeer.

WI
353
*** Example  Pink or Blue
Asking the player to select a gender to begin play.

WI
262
*** Example  Baritone, Bass
Letting the player pick a gender (or perhaps other characteristics) before starting play.

WI

The "reading a command" activity is rather advanced; for the moment, what we need to understand is that we're intervening in commands at the start of play and insisting that the player's first instruction to the game consist of a choice of gender. After that point, the gender will be set and play will proceed as normal.

In order to do the parsing, we define gender as a kind of value, and give several alternate names to each gender.

"Baritone, Bass"

Getting Started is a room.

Gender is a kind of value. The genders are masculine, feminine, and unknown. Understand "male" or "man" or "M" as masculine. Understand "female" or "woman" or "F" as feminine.

A person has a gender. The gender of the player is unknown.

When play begins:
    change the command prompt to "Please choose a gender for your character. >";

After reading a command when the gender of the player is unknown:
    if the player's command includes "[gender]"
    begin;
        now the gender of the player is the gender understood;
        if the gender of the player is masculine, now the player is male;
        if the gender of the player is feminine, now the player is female;
        say "[line break]Thank you. We now begin...";
        change the command prompt to ">";
        move the player to Sandy Beach;
        reject the player's command;
    otherwise;
        say "Sorry, we're not ready to go on yet -- please pick a gender to begin. >";
        reject the player's command;
    end if.

Sandy Beach is a room.

Instead of examining the player when the player is female:
    say "Congratulations, you are a girl!"

Instead of examining the player when the player is male:
    say "Congratulations, you are a boy!"

If we had a whole series of things to ask the player about, we might define a whole series of kinds of value

The vocal ranges are soprano, mezzosoprano, contralto...

and use a "construction stage" variable to keep track of the current stage of character-construction, as in

After reading a command when the current construction stage is choosing a vocal range:
    ...

216
* Example  rBGH
The player character's height is selected randomly at the start of play.

WI


PreviousContentsNext